Download code

From LiteratePrograms

Back to Mind_reading_machine_(AWK)

Download for Windows: single file, zip

Download for UNIX: single file, zip, tar.gz, tar.bz2

mindreader.awk

 # Copyright (c) 2010 the authors listed at the following URL, and/or
 # the authors of referenced articles or incorporated external code:
 # http://en.literateprograms.org/Mind_reading_machine_(AWK)?action=history&offset=20090511092403
 # 
 # Permission is hereby granted, free of charge, to any person obtaining
 # a copy of this software and associated documentation files (the
 # "Software"), to deal in the Software without restriction, including
 # without limitation the rights to use, copy, modify, merge, publish,
 # distribute, sublicense, and/or sell copies of the Software, and to
 # permit persons to whom the Software is furnished to do so, subject to
 # the following conditions:
 # 
 # The above copyright notice and this permission notice shall be
 # included in all copies or substantial portions of the Software.
 # 
 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
 # EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
 # MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
 # IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY
 # CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
 # TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
 # SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
 # 
 # Retrieved from: http://en.literateprograms.org/Mind_reading_machine_(AWK)?oldid=16430
 
 BEGIN	{
 	print "+--------------------------------------------------------------+"
 	print "| An AWKward mind-reading machine                              |"
 	print "|         (this retrogame inspired by the Bell Labs Memo:      |"
 	print "|          Shannon, 1953, 'A Mind-Reading (?) Machine')        |"
 	print "+--------------------------------------------------------------+"
 	print "Shall we play a game?"
 	print "Tell me either 'heads' or 'tails'."
 	print "If I guess what you picked, I win.  Otherwise, you win."
 	print "The match goes for 100 rounds, or until one player is up by 20."
 	printf "your play? "
 	}
 #BEGIN	{ "date +%s" | getline seed; srand(seed) }

 
 BEGIN	{ t = 0 }
 NR > 2	{
 	case = (hpa!=hca)"/"(hpa!=hpb)"/"(hpb!=hcb)
 	t = tally[case]
 	}
 
 t < -1	{ guess=!hpb }
 t == -1 { guess=(int(rand()+.75)?!hpb:hpb) }
 t == 0	{ guess=int(rand()+.5) }
 t == 1  { guess=(int(rand()+.75)?hpb:!hpb) }
 t > 1	{ guess= hpb }
 
 /^[hH]/		{ play=1 }
 /^[tT]/		{ play=0 }
 /^[^hHtT]/	{ printf "heads or tails? "; next }
 
 	{
 	printf "You played " (play?"heads":"tails")
 	printf "; I guessed " (guess?"heads":"tails")
 	printf ".  "(play==guess?"I":"You")" win. "
 	print "("(pw+=(play!=guess))"-"(cw+=(play==guess))")"
 	}
 
 NR > 2	{ tally[case] += (hpb == play ? 1 : -1) }
 	{
 	hpa = hpb; hpb = play
 	hca = hcb; hcb = guess
 	}
 
 cw+pw==100	{ printf (cw>pw?"I":"You")" won the match "
 		  print  "by "(cw>pw?cw-pw:pw-cw)" games."
 		  exit }
 pw-cw==20	{ print "You win -- up by 20"; exit }
 cw-pw==20	{ print "I win -- up by 20"; exit }
 		{ printf "? " }
 
 END	{ 
 	print " T H A N K   Y O U   F O R   P L A Y I N G "
 	}